Hi, Saturday (6 March 2004)
Per our discussion at last Thursday's PWG Process telecon, below is a
sequence of document filenames, created by a hypothetical PWG working
group 'ABC', showing the 'life cycle' of PWG documents:
(a) development of requirements document;
(b) development of protocol document;
(c) editorial update of protocol document - same minor version
- WITHOUT parameter, encoding, attribute, or value changes;
(d) technical update of protocol document - new minor version
- WITH parameter, encoding, attribute, or value changes.
Notes:
(1) A commented ABNF for PWG document filenames is specified below.
(2) Working drafts of previous Candidate Standards undergoing revision
SHOULD drop their standards number (51xy.z) until the revised
document is finally approved by Formal Vote.
(3) The file prefix 'wp' (white paper) has been combined with 'tb'
(technical brief) as the common informal note document type
(also, 'wp' was too close to 'wd' for clarity).
(4) The file prefix 'dg' (developer's guide) has been combined with
'bp' (best practice) and SHOULD require a Formal Vote of approval
(because it uses SHOULD and SHOULD NOT).
(5) IETF concept of 'class' is introduced, with 'white paper', 'draft',
and 'standards track' document types (see ABNF below).
(6) ISO/W3C concept of 'edition' is introduced, appended to major/minor
version (in document titles ONLY, not filenames), to disambiguate
purely editorial revisions (see examples in sequence below).
Comments?
Cheers,
- Ira
Ira McDonald (Musician / Software Architect)
Blue Roof Music / High North Inc
PO Box 221 Grand Marais, MI 49839
phone: +1-906-494-2434
email: imcdonald at sharplabs.com
------------------------------------------------------------------------
PWG document filename ABNF (see RFC 2234 for ABNF types used below):
pwgfilename = whitefile / draftfile / stdfile
whitefile = whitepfx "-" 1*(lowalpha / digit / "-") "-" date "." ext
draftfile = draftpfx "-" wg [spec] version "-" date "." ext
stdfile = stdpfx "-" wg [spec] version "-" date "-" stdnum "." ext
whitepfx = "faq" / ; frequently asked questions
"ht" / ; hints & tips (no SHOULD/MUST)
"tb" ; technical brief (note)
draftpfx = "wd" / ; working draft
"lcrc" ; last call review comments
stdpfx = "std" / ; Standard (w/ MUST)
"cs" / ; Candidate Standard (w/ MUST)
"bp" ; Best Practice (w/ SHOULD)
wg = 2*(lowalpha) ; working group email list
spec = 2*(lowalpha) ; omitted for base protocol
version = major minor ; version of protocol/interface
major = 1*digit ; NEED NOT be compatible
minor = 1digit ; MUST be backwards compatible
date = year month day ; 8-digit date
year = 4digit
month = 2digit
day = 2digit
stdnum = "51" 2digit "." 1*digit ; IEEE/ISTO PWG standard number
ext = "doc" / ; MS Word document source
"htm" / ; HTML document source
"pdf" / ; Adobe PDF document formatted
"txt" / ; UTF-8 document plaintext
"xml" / ; XML document source
"xsd" / ; XML schema source
1*3lowalpha ; other 1-3 character extension
------------------------------------------------------------------------
1) ABC WG is chartered
- with the 'abc at pwg.org' mailing list name
2) ABC WG directories are created, including:
- ftp://ftp.pwg.org/pub/pwg/abc - primary directory
- ftp://ftp.pwg.org/pub/pwg/abc/wd - working drafts
- ftp://ftp.pwg.org/pub/pwg/abc/white - FAQs/technical briefs/hints
- ftp://ftp.pwg.org/pub/pwg/abc/schemas - XML schemas
- ftp://ftp.pwg.org/pub/pwg/abc/minutes - minutes of WG meetings
- ftp://ftp.pwg.org/pub/pwg/abc/slides - slides and presentations
3) first draft ABC requirements (working draft)
- .../abc/wd/wd-abcreq10-20040505.doc/pdf
4) last draft to PWG Announce - 30 day 'last call' (working draft)
- .../abc/wd/wd-abcreq10-20040814.doc/pdf
5) last draft to PWG Announce - 30 day Formal Vote (working draft)
- .../abc/wd/wd-abcreq10-20040814.doc/pdf
6) "PWG ABC Requirments/1.0 - 1st Edition" (Candidate Standard)
- .../candidates/cs-abcreq10-20041108-5109.1.doc/pdf
7) first draft ABC protocol (working draft)
- .../abc/wd/wd-abc10-20041212.doc/pdf
8) last draft to PWG Announce - 30 day 'last call' (working draft)
- .../abc/wd/wd-abc10-20050404.doc/pdf
9) last draft to PWG Announce - 30 day Formal Vote (working draft)
- .../abc/wd/wd-abc10-20050404.doc/pdf
10) "PWG ABC Protocol/1.0 - 1st Edition" (Candidate Standard)
- .../candidates/cs-abc10-20050715-5109.2.doc/pdf
11) first draft ABC protocol update (working draft)
- ONLY editorial revisions - same minor version
- .../abc/wd/wd-abc10-20050802.doc/pdf
12) last draft to PWG Announce - 30 day 'last call' (working draft)
- .../abc/wd/wd-abc10-20051005.doc/pdf
13) last call review comments - with embedded issues and resolutions
- .../abc/wd/lcrc-abc10-20051105.doc/pdf
14) last draft to PWG Announce - 30 day Formal Vote (working draft)
- .../abc/wd/wd-abc10-20051120.doc/pdf
15) "PWG ABC Protocol/1.0 - 2nd Edition" (Candidate Standard)
- .../candidates/cs-abc10-20051225-5109.2.doc/pdf
16) technical brief about ABC protocol performance (white paper)
- .../abc/white/tb-abc10-performance-20060113.doc/pdf
17) FAQ about ABC protocol (white paper)
- .../abc/white/faq-abc10-20060220.doc/pdf
18) first draft ABC protocol update (working draft)
- technical revisions - new minor version
- .../abc/wd/wd-abc11-20060310.doc/pdf
19) last draft to PWG Announce - 30 day 'last call' (working draft)
- .../abc/wd/wd-abc11-20060812.doc/pdf
20) last call review comments - with embedded issues and resolutions
- .../abc/wd/lcrc-abc11-20060912.doc/pdf
21) last draft to PWG Announce - 30 day Formal Vote (working draft)
- .../abc/wd/wd-abc11-20060930.doc/pdf
22) "PWG ABC Protocol/1.1 - 1st Edition" (Candidate Standard)
- .../candidates/cs-abc11-20061123-5109.2.doc/pdf